hogyan kell végrehajtani a .bat fájlt egy .bat fájlon belül, különböző útvonallal?

Ne nevezzen el egy kötegfájlt úgy, mint a Windows parancsfeldolgozó belső parancsát vagy a Windows system32 könyvtárában tárolt szabványos Windows konzolalkalmazást. A @ START BAT.bat határozottan nem jó név kötegfájlnak, mert tartalmazza a start parancsot, szóközt tartalmaz a fájlnévben, és a @ is nagyon szokatlan a fájlnevekben, ami az oka annak, hogy sok évvel ezelőtt ezt a karaktert választották elválasztóként az e-mail címekben.

A "W:\PROJÉČŤ és "K:\PROJÉČŤ minden almappájában egy nem FILE.avi FILE.avi nevű AVI-fájl átnevezése (remélhetőleg) és az írásvédett attribútum eltávolítása elvégezhető a következő kötegkóddal a AviFileRename.bat mappába mentve:

@echo off
call :AviFileRename "W:\PROJÉČŤ"
call :AviFileRename "K:\PROJÉČŤ"
goto :EOF

:AviFileRename
for /R %1 %%# in (*.avi) do (
    if /I "%%~n#" == "FILE" (
        %SystemRoot%\System32\attrib.exe -r "%%#"
    ) else (
        ren "%%#" "FILE.avi"
        %SystemRoot%\System32\attrib.exe -r "%%~dp#FILE.avi"
    )
)

Nem számít, hogy a AviFileRename.bat melyik könyvtárba van mentve ezekkel a kódsorokkal.

A használt parancsok és működésük megértéséhez nyisson meg egy parancssori ablakot, hajtsa végre a következő parancsokat, és nagyon figyelmesen olvassa el az egyes parancsokhoz megjelenő összes súgóoldalt.

• attrib /?
• call /?
• echo /?
• for /?
• goto /?
• if /?
• ren /?

A hívás parancs általában a fő köteg feldolgozásának folytatására használható egy alkötegben, és amikor az alköteg feldolgozása befejeződött, folytassa a fő köteg feldolgozását. Részletekért olvassa el a választ: Hogyan hívhat meg kötegelt fájlt az aktuális kötegfájl szülőmappájában?

A /B opció nélküli exit parancs azonban a teljes parancsfolyamat kilépését eredményezi, nem csak az aktuális kötegfájl feldolgozását. Részletekért olvassa el a következő választ: Windows kötegfájlban végrehajthat-e olyasmit, amely nem egy másik kötegfájl. ? És olvassa el a súgó kimenetét, amikor fut egy parancssori ablakban (exit /?). A megoldás az, hogy a start paranccsal futtassa a kötegfájlt egy új parancsfolyamatban.

De csak használ

START "K:\PROJÉČŤ\A B1\@ START BAT.bat"

nem elég, mert

1. A start parancs az idézőjelben lévő első karakterláncot nem kötelező címként értelmezi – a részletekért futtassa a parancssori ablakban start /?;

2. az aktuális könyvtár nincs beállítva az elindított kötegfájl könyvtárára, amint azt a K:\PROJÉČŤ\A B1 @ START BAT.bat sorai megkövetelik.

A működő parancssor a következő lenne:

start "Processing A B1" /D"K:\PROJÉČŤ\A B1" "K:\PROJÉČŤ\A B1\@ START BAT.bat"

Ez a parancs a REM paranccsal a W:\PROJÉČŤ\A A1\@ START BAT.bat-ba kerül sor helyett.

A paraméterek magyarázatát lásd a start /? kimenetében:

1. "Processing A B1" ... az új folyamatablak címe. Lehetséges egy üres karakterlánc is, amelyet a "" karakterlánc határoz meg. De valami, amit az ember is olvashat ablakcímként, mindig jobb, mint egy cím nélküli konzolablak. Ha a parancssorban bármilyen más paramétert dupla idézőjelekkel adunk meg, akkor meg kell adni a címet.

2. /D"K:\PROJÉČŤ\A B1" ... meghatározza az új parancsfolyamat munkakönyvtárát.

3. "K:\PROJÉČŤ\A B1\@ START BAT.bat" ... az indítandó parancs / végrehajtható / szkript ebben az esetben a @ START BAT.bat kötegfájl a K:\PROJÉČŤ\A B1 könyvtárban.

Érdemes lehet a /D"K:\PROJÉČŤ\A B1" után hozzáadni a /wait start paramétert, hogy a kötegfájlt az új parancsfolyamatban futtassa, és a W:\PROJÉČŤ\A A1\@ START BAT.bat feldolgozását mindig leállítsa, amíg az elindított kötegfájl be nem fejeződik, és a parancsfolyamat ki nem fejeződik a paranccsal. kilépést, vagy amikor a kötegfájl utolsó sorát feldolgozta a parancsfeldolgozó.

De van még egy probléma a PROJÉČŤ mappanévvel. Nem ASCII karaktereket tartalmaz ÉČŤ, ezért fontos, hogy a kötegfájl szerkesztésére használt szövegszerkesztőben a megfelelő kódlap legyen beállítva, különben a PROJÉČŤ könyvtár nem található. A konzolablak kódlapja a Windows régiótól és nyelvi beállításaitól függ.

Ha egy parancssori ablakban futtatja a chcp parancsot, akkor megjelenik a parancsfolyamatokhoz meghatározott kódlap a gépén. Ezt (általában) az OEM kódlapot kell használni a szövegszerkesztőben is, nem pedig az ANSI (Windows) kódlapot, amelyet a szövegszerkesztő általában használ szövegfájlok szerkesztéséhez.

Rendben van, ha szóközök vannak a fájlnévben, és a @ nem olyan karakter, amelyet ki kell cserélni. Ennek ellenére néha sokkal könnyebb elnevezni a kötegfájlokat speciális karakterek vagy szóközök nélkül, és kötőjeleket használni a szavak között, például my-cool-script.bat.

Íme egy példa, amelynek utánoznia kell, amit csinál, és ez segít a szkriptek hibakeresésében.

Directory of L:\test

12/27/2015  11:12 AM    <DIR>          .
12/27/2015  11:12 AM    <DIR>          ..
12/27/2015  11:12 AM               118 @ start one.bat
12/27/2015  11:08 AM                56 @ start two.bat

L:\test>"@ start one.bat"
ONE
Running "@ start one.bat"
Calling @ start two.bat
TWO
Running "L:\test\@ start two.bat"
Bye from "L:\test\@ start two.bat"
Bye from "@ start one.bat"

És itt van a kötegfájlok tartalma:

L:\test>type *.bat

@ start one.bat


@echo off
echo ONE
echo Running %0
echo Calling @ start two.bat
call "L:\test\@ start two.bat"
echo Bye from %0

@ start two.bat


@echo off
echo TWO
echo Running %0
echo Bye from %0

Ez akkor is működik, ha a fájlok különböző könyvtárakban vannak:

Directory of L:\test

12/27/2015  11:35 AM    <DIR>          one
12/27/2015  11:35 AM    <DIR>          two

Directory of L:\test\one

12/27/2015  11:35 AM               116 @ start one.bat

Directory of L:\test\two

12/27/2015  11:35 AM                54 @ start two.bat

L:\test>"one\@ start one.bat"
ONE
Running "one\@ start one.bat"
Calling @ start two.bat
TWO
Running "L:\test\two\@ start two.bat"
Bye from "L:\test\two\@ start two.bat"
Bye from "one\@ start one.bat"

És az első bat fájl frissített tartalma:

L:\test>type "one\@ start one.bat"
@echo off
echo ONE
echo Running %0
echo Calling @ start two.bat
call "L:\test\two\@ start two.bat"
echo Bye from %0

Egy másik frissítés, amely bemutatja, hogyan lehet hivatkozni a szkript aktuális könyvtárára, nem csak a szkript indulásának „aktuális könyvtárára”.

%~dp0 itt a kulcs...

L:\test>dir /s
Directory of L:\test
12/27/2015  03:12 PM    <DIR>          one
12/27/2015  03:12 PM    <DIR>          two

Directory of L:\test\one
12/27/2015  03:17 PM               170 @ start one.bat
12/27/2015  03:12 PM                 8 file.txt

Directory of L:\test\two
12/27/2015  03:17 PM               104 @ start two.bat
12/27/2015  03:12 PM                13 file.txt

EGY

@echo off
echo ONE
echo Running %0
echo From Directory: %~dp0
echo Calling @ start two.bat
dir "%~dp0\file.txt"
call "L:\test\two\@ start two.bat"
echo Bye from %0

KETTŐ

@echo off
echo TWO
echo Running %0
echo From Directory: %~dp0
dir "%~dp0\file.txt"
echo Bye from %0

KIMENET

L:\test>"one\@ start one.bat"
ONE
Running "one\@ start one.bat"
From Directory: L:\test\one\
Calling @ start two.bat

Directory of L:\test\one

12/27/2015  03:12 PM                 8 file.txt
           1 File(s)              8 bytes

TWO
Running "L:\test\two\@ start two.bat"
From Directory: L:\test\two\

Directory of L:\test\two

12/27/2015  03:12 PM                13 file.txt
           1 File(s)             13 bytes
Bye from "L:\test\two\@ start two.bat"
Bye from "one\@ start one.bat"

L:\test>

Mindennek rendelkeznie kell a szkriptek javításához.